3 + (u=. 12 : t) ^. 4

12   

	u

õýýýýýýýýýýýýýýýýýÃýÃýýÀ
þõýýýýýýýýýýÃýÃýýÀþ&þ].þ
þþõýýÃýýÃýýÀþ@þ[.þþ þ  þ
þþþ].þ^:þ_1þþ þ  þþ þ  þ
þþÁýýÂýýÂýýãþ þ  þþ þ  þ
þÁýýýýýýýýýýÂýÂýýãþ þ  þ
ÁýýýýýýýýýýýýýýýýýÂýÂýýã
]. ^: _1 @ [. & ].  


Exercises:

20.1 Use the display of the tacit definition of MEAN to define an
equivalent function called M.

ANSWER: M=. +/ % #

21:  RANK

The shape ($), tally (#), and rank (#@$), of a noun are illustrated by
the noun report, which may be construed as a report covering two years
of four quarters of three months each:

	]report=. i. 2 4 3

 0  1  2		  $report
 3  4  5		2 4 3
 6  7  8		  #report
 9 10 11		2
			  #@$report
12 13 14		3
15 16 17
18 19 20
21 22 23

The last k axes determine a k-cell of a noun; the 0-cells of report are
the atoms (such as 4 and 14), the 1-cells are the three-element
quarterly reports, and the two-cells (or major cells or items) are the
two four-by-three yearly reports.  The rank conjunction " is used in
the phrase f"k to apply a function f to each of the k-cells of its
argument. For example:
	,report

0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23

	,"2 report

 0  1  2  3  4  5  6  7  8  9 10 11
12 13 14 15 16 17 18 19 20 21 22 23

	<@i. s=. 2 5	     <@i."0 s

õýýýýýýýýýÀ		õýýýÃýýýýýýýýýÀ
þ0 1 2 3 4þ		þ0 1þ0 1 2 3 4þ
þ5 6 7 8 9þ		ÁýýýÂýýýýýýýýýã
Áýýýýýýýýýã

Both the left and right ranks of a dyad may be specified. Thus:
	i,"0 1 i=.0 1 2	   i,"1 1 i

0 0 1 2		0 1 2 0 1 2
1 0 1 2		   ,"1~i
2 0 1 2		0 1 2 0 1 2

The basic characteristics adverb b. is very useful in analyzing
functions (or expressions that define them) with respect to their
ranks.  For example:

	# b. 0	   +/\ b. 0	(+/\ % #) b. 0

_ 1 _ 		_ 0 _ 			_ 1 _


Exercises:

21.1  Observe the results of the following uses of the monads produced
by the rank conjunction, and comment on them:
		a=. i. 3 4 5
		<"0 a
		<"1 a
		<"2 a
		<"3 a
		< a
		<"_1 a
		<"_2 a
		mean=. +/ % #
		mean a
		mean"1 a
		mean"2 a

ANSWER: <"k applies < to each cell of rank k, with <"(#$a) a being
equivalent to <a. Moreover, a negative value of k specifies a
complementary rank that is effectively |k less than the rank of the
argument a.

21.2  Use the results of the following experiments to state the
relation between the conjunctions @ (Atop) and @: (At), and compare
your conclusions with the dictionary definition:

		(g=. <"2) a=. i. 3 4 5
		|. @: g a
		|. @ g a
		|: @: (<"1) a
		|: @ (<"1) a

ANSWER: The rank of the function |. @: g is itself infinite and |.
therefore

applies to the entire list result of g a, consequently  reversing it.
On the other hand, the function f @ g inheritsthe rank of g, and |.
therefore applies individually to the atoms produced by g, producing no
effect.

21.3 Use the results of the following experiments to comment on the use
of the rank conjunction in dyads:

		b=. 'ABC'

		c=. 3 5 $ 'abcdefghijklmno'
		c
		b,c
		b ,"0 1 c
		b ,"1 1 c
		b ,"1 c

22:  GERUND AND AGENDA

In English, a gerund is a noun that carries the force of a verb, as
does the noun cooking in the phrase the art of cooking; and agenda is a
list of items for action.  The tie conjunction ` applies to two verbs
to form a gerund, from which elements can be chosen for execution.
Thus, if the agenda conjunction @. is applied to a gerund, its verb
right argument provides the results that choose the elements. For
example:

	g=. +`^
	a=.<
	2 a 3

1

	2 g@.a 3

8

	3 g@.a 2

5

	+:`-:`*:`%: @. (4&|@<.)"0 i. 10

0 0.5 4 1.73205 8 2.5 36 2.64575 16 4.5

The verb produced by g@.a is often called a case or case statement,
since it selects one of the cases of the gerund for execution.

The insert adverb / applies to a gerund in a manner analogous to its
application to a verb. For example:

	c=.3 [ x=. 4 [ power=. _1
	g/ c,x,power

3.25

	3+x^_1

3.25

The elements of the gerund are repeated as required. For example:
	+`*/1,x,3,x,3,x,1

125

The last sentence above corresponds to Horner's efficient evaluation of
the polynomial with coefficients 1 3 3 1 and argument x.


Exercises:

22.1 Define a function f such that (x=. 4) f c=. 1 3 3 1 yields the
result used as the argument to +`*/ in Horners method in Lesson 22.

ANSWER: f=. }.@,@,.

23:  RECURSION

The factorial function ! is commonly defined by the statement that
factorial n is n times factorial n-1, and by the further statement that
factorial 0 is 1. Such a definition is called recursive, because the
function being defined recurs in its definition.  A case statement can
be used to make a recursive definition, the case that employs the
function under definition being chosen repeatedly until the terminating
case is encountered. For example:

	factorial=. 1:`(]*factorial@<:) @. *
	factorial "0 i.6

1 1 2 6 24 120

In the sentence (sum=. +/) i.5 the verb defined by the phrase +/ is
assigned a name before being used, but in the sentence +/ i.5 it is
used anonymously.  In the definition of factorial above, it was
essential to assign a name to make it possible to refer to it within
the definition. However, the word $: provides self-reference that
permits anonymous recursive definition. For example:

	1:`(]*$:@<:) @. * "0 i. 6

1 1 2 6 24 120

In the Tower of Hanoi puzzle, a set of n discs (each of a different
size) is to be moved from post A to post B using a third post C and
under the restriction that a larger disc is never to be placed on a
smaller. The following is a recursive definition of the process:

   h=. b`(p,.q,.r)@.c
     c=. 1: < [
     b=. 2&,@[ $ ]
       p=. <:@[ h 1: A. ]
       q=. 1: h ]
       r=. <:@[ h 5: A. ]
   3 h x=. 'ABC'

AABACCA
BCCBABB

   0 1 2 3 4 <@h"0 1 x

õÃýÃýýýÃýýýýýýýÃýýýýýýýýýýýýýýýÀ
þþAþAACþAABACCAþAACABBAACCBCAACþ
þþBþCBBþBCCBABBþCBBCACCBBAABCBBþ
ÁÂýÂýýýÂýýýýýýýÂýýýýýýýýýýýýýýýã 		


Exercises:

23.1  Use the following as exercises in reading and writing:
		f=.1:`(+//.@(,:~)@($:@<:))@.*   			Binomial Coeffs

		<@f"0 i.6	         	      		Boxed binomials
		g=.1:`((],+/@(_2&{.))@$:@<:)@.* 		Fibonacci 

24:  ITERATION

The repetition of a process, or of a sequence of similar processes, is
called iteration. Much iteration is implicit, as in */b and a*/b, and
a*b; explicit iteration is provided by the power conjunction (^:), by
agenda (@.) with self-reference, and by control structures:
	(cos=. 2&o.) ^: (i.6) b=. 1

1 0.540302 0.857553 0.65429 0.79348 0.701369

	]y=. cos^:_ b		     y=cos y

0.739085			  1

The example cos^:_ illustrates the fact that infinite iteration is
meaningful (that is, terminates) if the process applied converges.
Controlled iteration of a process p is provided by p^:q, where the
result of q determines the number of applications of p performed. A
zero result from q terminates the process. The form $:@p^:q is commonly
useful.  If f is a continuous function, and if f i and f j differ in
sign, then there must be a root r between i and j such that f r is
zero; the list b=.i,j is said to bracket a root. A narrower bracket is
provided by the mean of b together with that element of b whose result
on applying f differs in sign from its result . Thus:

	f=. %: - 4:		A sample function
	root=. 3 : 0

m=. +/ % #
while. ~:/y.
do.
	if. ~:/ * f ({.,m) y.
	   do. y.=. ({.,m) y.
	 else. y.=. ({:,m) y.
	end.
end. m y.  
)

	b=. 1 32
	root b

16

	f b,root b

_3 1.65685 1.77636e_15			


Exercises:

24.1 Use the function BR of Lesson 24 to find the roots of various
functions, such as
f=. 6&-@!

24.2 Experiment with the function fn=. +/\ (which produces the figurate
numbers when applied repeatedly to i.n), and explain the behaviour of
the function fn^:(?@3:)

25:  TRAINS

The train of nouns in the English phrase Ontario museum Egyptian
collection represents a single noun. Similarly, the fork and hook
discussed in Lesson 6 and its exercises permit the use of arbitrarily
long trains of verbs to produce a verb.  Lesson 16 introduced the use
of trains of adverbs, and of conjunctions together with nouns or verbs,
to represent adverbs.  Conjunctions may also be produced by trains of
adverbs and conjunctions in a manner analogous to hooks and forks.

For example, the case diagrammed on the right below can be used as
follows:
	cj=.\@\					
	< cj (+/) a=.i.3 3				  	  c

õýýýýýÃýýýýýÃýýýýýýýÀ					 / \
þ0 1 2þ0 1 2þ0  1  2þ					a1 a2
þ     þ3 5 7þ3  5  7þ					|   |
þ     þ     þ9 12 15þ					x   y
ÁýýýýýÂýýýýýÂýýýýýýýã

	(<\)@(+/\) a		      (*/) cj (+/) a

õýýýýýÃýýýýýÃýýýýýýýÀ		    0  1   2
þ0 1 2þ0 1 2þ0  1  2þ		    0  5  14
þ     þ3 5 7þ3  5  7þ		    0 60 210
þ     þ     þ9 12 15þ
ÁýýýýýÂýýýýýÂýýýýýýýã

The explicit form of defining conjunctions treated in the exercises of
Lesson 19 can be used to produce an equivalent conjunction CJ as shown
below. The corresponding tacit definition is produced by 12 : s  :
	s=. 0 : 0

(x.\)@(y.\)
)  

	CJ=. 2 : s            
	(*/) CJ (+/) a        

0  1   2                
0  5  14                
0 60 210  

	12 : s

\ @ \


Exercises:

25.1 Use the display of 12 : s in Lesson 25 as a guide in defining an
equivalent conjunction C, and compare the resulting definition with the
simpler definition used for cj in Lesson 25.

26:  PERMUTATIONS

Anagrams are familiar examples of the important notion of permutations:
	w=. 'STOP'
	3 2 0 1 { w

POST

	2 3 1 0 { w

OPTS

	3 0 2 1 { w

PSOT

The left arguments of { above are themselves permutations of the list
i.4, and are examples of permutation vectors, used to represent
permutation functions in the form p&{.  If p is a permutation vector,
the phrase p&C. also represents the permutation p&{. However, other
cases of the cycle function C. are distinct from the from function {.
In particular, C. p yields the cycle representation of the permutation
p. For example:

	]c=. C. p=. 2 4 0 1 3

õýýýÃýýýýýÀ
þ2 0þ4 3 1þ
ÁýýýÂýýýýýã

	c C. 'ABCDE'		   C. c

CEABD			2 4 0 1 3

Each of the boxed elements of a cycle specify a list of positions that
cycle among themselves; in the example above, the element from position
3 moves to position 4, element 1 moves to 3, and element 4 to 1.  If
all !n permutations of order n are listed in a table in increasing
order (when considered as base-n numbers), they can be identified by
their row indices i.!n. This index is the atomic representation of the
permutation; the corresponding permutation is effected by the function
A.:

	1 A. 'ABCDE'		   A. 0 1 2 4 3

ABCED			1

	(i.!3) A. i.3		   (i.!3) A. 'ABC'

0 1 2			ABC
0 2 1			ACB	
1 0 2			BAC	  
1 2 0			BCA	  
2 0 1			CAB
2 1 0			CBA	


Exercises:

26.1 Use the following as exercises in reading and writing (try on
a=.'abcdef' and b=.i. 6 and c=. i. 6 6):

		f=. 1&A.		Interchange last two items

		g=. 3&A.		Rotate last three items
		h=. 5&A.		Reverse last three items
		i=. <:@!@[ A. ]		k i a reverses last k items.

26.2 Experiment with the following expressions and others like them to
determine the rules for using abbreviated arguments to C. and compare
your conclusions with the dictionary definitions:

		2 1 4 C. b=.i.6
		(<2 1 4) C. b
		(3 1;5 0) C. b

26.3  Make a program ac that produces a table of the cycle
representations of all permutations of the order of its argument, as in
ac 3.

ANSWER: ac=. C.@(i.@! A. i.)

27:  LINEAR FUNCTIONS

A function f is said to be linear if f(x+y) equals (f x)+(f y) for all
arguments x and y. For example:
	f=.3&|.@+:@|.
	]x=. i.# y=.2 3 5 7 11

0 1 2 3 4

	x+y			   f x+y

2 4 7 10 15			8 4 30 20 14

	(f x),:(f y)		   (f x)+(f y)

2 0  8  6  4		8 4 30 20 14
6 4 22 14 10

A linear function can be defined equivalently as follows: f is linear
if f@:+ and +&f are equivalent. For example:
	x f@:+ y		   x +&f y

8 4 30 20 14		8 4 30 20 14

If f is a linear function, then f y can be expressed as the matrix
product  mp&M y, where
	mp=. +/ . *
	M=. f I=. =/~i.#y		 I is an identity matrix
	mp&M y			   f y

6 4 22 14 10		6 4 22 14 10

Conversely, if m is any square matrix of order #y, then m&mp is a
linear function on y, and if m is invertible, then (%.m)&mp is its
inverse:
	x=. 1 2 3 [ y=. 2 3 5
	]m=. ? 3 3$9

5 7 3
7 2 3
4 4 2

	]n=. %.m

 _1.33333 _0.333333  2.5
_0.333333 _0.333333    1
  3.33333   1.33333 _6.5

	g=. mp&m
	h=. mp&n
	x g@:+ y		   x +&g y

82 63 40			82 63 40	

	g h y

2 3 5


Exercises:

27.1  For each of the following functions, determine the matrix M such
that M(mp=. +/ . *) N is equivalent to the result of the function
applied to the matrix N, and test it for the case N=. i. 6 6 :
		|.
		-
		+:
		(4&*-2&*@|.)
		2&A.

28:  OBVERSE AND UNDER

The result of f^:_1 is called the obverse of the function f; if f=. g
:. h, this obverse is h, and it is otherwise an inverse of f. Inverses
are provided for over 25 primitives (including the case of the square
root illustrated in Lesson 12), as well as invertible monads such as
-&3 and 10&^. and 2&o. . Moreover, u@v^:_1 is given by (v^:_1)@(u^:_1).
For example:
	fFc=. (32&+)@(*&1.8)

	]b=.fFc _40 0 100

_40 32 212

	cFf=. fFc^:_1
	cFf b

_40 0 100

The result of the phrase f &. g is the verb (g^:_1)@(f & g) . The
function g can be viewed as preparation (which is done before and
undone after) for the application of the main function f . For
example:
	b=. 0 0 1 0 1 0 1 1 0 0 0
	sup=. </\	 	Suppress ones after the first
	sup b

0 0 1 0 0 0 0 0 0 0 0

	|. sup |. b		Suppress onesábefore the last

0 0 0 0 0 0 0 1 0 0 0

	sup&.|. b			      "

0 0 0 0 0 0 0 1 0 0 0

	3 +&.^. 4		Multiply by applying the exponential 

12				to the sum of logarithms

	(^.3)+(^.4)	

2.48491

	^ (^.3)+(^.4)