2 %: b				Square root of b
2 2.23607 2.44949 2.64575 2.82843 3
	3 %: b				Cube root of b
1.5874 1.70998 1.81712 1.91293 2 2.08008

	(+/ % #) b			Arithmetic mean or average
6.5
	(# %: */) b			Geometric mean
6.26521
	(] - (+/ % #)) b			Centre on mean (two forks)
_2.5 _1.5 _0.5 0.5 1.5 2.5
	(] - +/ % #) b			Two forks (fewer parentheses)
_2.5 _1.5 _0.5 0.5 1.5 2.5
	a (+ * -) b			Dyadic case of fork
48 24 0 _24 _48 _72
	(a^2)-(b^2)
48 24 0 _24 _48 _72
	a (< +. =) b			Less than or equal
0 0 1 1 1 1
	a<b			   
0 0 0 1 1 1		

	a=b
0 0 1 0 0 0
	a (<: = < +. =) b			A tautology (<: is less than
1 1 1 1 1 1				or equal)
	2 ([: ^ -) 0 1 2			Cap yields monadic case
7.38906 2.71828 1


Exercises:

6.1     Enter 5#3 and similar expressions to determine the definition
of the dyad # and then state the meaning of the following sentence:

	 	(# # >./) b=. 2 7 1 8 2
ANSWER: #b repetitions of the maximum over b 

6.2     Cover the comments on the right, write your own interpretation
of each sentence, and then compare your statements with those on the
right:

	(+/ % #) b		Mean of b

	(# # +/ % #) b		(n=.#b) repetitions of mean
	+/(##+/%#) b		Sum of n means
	(+/b)=+/(##+/%#) b		Tautology
	(*/b)= */(###%:*/) b		The product over b is the product over n
 					    repetitions of the geometric mean of b.		

7:  PROGRAMS

A program handed out at a musical evening describes the sequence of
musical pieces to be performed. As suggested by its roots gram and pro,
a program is something written in advance of the events it prescribes.

Similarly, the fork +/ % # of the preceding lesson is a program that
prescribes the computation of the mean of its argument when it is
applied, as in the sentence (+/%#)b. However, we would not normally
call the procedure a program until we assign a name to it, as
illustrated below:
	mean=. +/ % #
	mean 2 3 4 5 6

4

	(geomean=. # %: */) 2 3 4 5 6

3.72792

Since the program mean is a new verb, we also refer to a sentence such
as mean=. +/ % # as verb definition (or definition), and to the
resulting verb as a definedverb or function.  Defined verbs can be used
in the definition of further verbs in a manner sometimes referred to as
structured programming. For example:
	MEAN=. sum % #
	  sum=. +/
	MEAN 2 3 4 5 6

4

Entry of a verb alone (without an argument) displays its definition,
and the foreign conjunction can be used to specify the form of the
display: boxed, tree, or linear:

	mean

+/ % #

	9!:3 (2 4 5)

	mean

õýýýýýÃýÃýÀ
þõýÃýÀþ%þ#þ
þþ+þ/þþ þ þ
þÁýÂýãþ þ þ
ÁýýýýýÂýÂýã
  õý / ýýý +
ýýÊý %      
  Áý #      
+/ % #


Exercises:

7.1	Enter AT=. i. +/ i. and use expressions such as AT 5 to determine the behaviour of the program AT.

7.2	Define and use similar function tables for other dyadic functions.
7.3	Define the programs:
	tab=. +/
	ft=. i. tab i.
	test1=. ft = AT
Then apply test1 to various integer arguments to test the proposition
that ft is equivalent to AT of Exercise 7.1, and enter ft and AT alone
to display their definitions.

7.4     Define aft=. ft f. and use test2=. aft = ft to test their
equivalence. Then display their definitions and state the effect of the
adverb f.

ANSWER: The adverb f. fixes the verb to which it applies,
 replacing each name used by its definition.

7.5	Redefine tab of Exercise 7.3 by entering tab=. */ and observe the effects on ft and its fixed alternative aft.
7.6	Define mean=. +/ % # and state its behaviour when applied to a table, as in
mean t=. (i. !/ i.) 5.

ANSWER: The result is the average of, not over, the rows of a table argument.

7.7	Write an expression for the mean of the columnsáof t.

ANSWER:  mean |: t or mean"1 t

8:  BOND CONJUNCTION

A dyad such as ^ can be used to provide a family of monadic functions:

	]b=. i.7

0 1 2 3 4 5 6

	b^2		Squares

0 1 4 9 16 25 36

	b^3		Cubes

0 1 8 27 64 125 216

	b^0.5		Square roots

0 1 1.41421 1.73205 2 2.23607 2.44949

The bond conjunction & can be used to bind an argument to a dyad in
order to produce a corresponding defined verb. For example:

	square=. ^&2	Square (power and 2)
	square b

0 1 4 9 16 25 36

	(sqrt=. ^&0.5) b	Square root function

0 1 1.41421 1.73205 2 2.23607 2.44949

A left argument can be similarly bound:

	Log=. 10&^.	Base-10 Logarithm
	Log 2 4 6 8 10 100 1000

0.30103 0.60206 0.778151 0.90309 1 2 3

Such defined verbs can of course be used in forks. For example:   

	in29=. 2&< *. <&9	Interval test

	in29 0 1 2 5 8 13 21
0 0 0 1 1 0 0
	IN29=. in29 # ]	Interval selection
	IN29 0 1 2 5 8 13 21
5 8

	LOE=. <+.=

	5 LOE 3 4 5 6 7

0 0 1 1 1
	integertest=. <. = ]                         The monad <. is integer part or floor
	integertest 0 0.5 1 1.5 2 2.5 3      
1 0 1 0 1 0 1
	int=. integertest
	int (i.13)%3

1 0 0 1 0 0 1 0 0 1 0 0 1


Exercises:


8.1     The verb # is used dyadically in the program IN29. Enter
expressions such as (j=. 3 0 4 0 1) # i.5 to determine the behaviour of
#, and state the result of #j#i.5. (Also try 1j1#i.5.)

ANSWER: +/j

8.2     Cover the answers on the right and apply the following programs
to lists to determine (and state in English) the purpose of each:

	test1=. >&10 *. <&100 	Test if in 10 to 100

	int=. ] = <.	    	Test if integer
	test2=. int *. test1 	Test if integer and in 10 to 100
	test3=. int +. test1 	Test if integer or in 10 to 100
	sel=. test2 # ]          		Select integers in 10 to 100

8.3     Cover the program definitions on the left of the preceding
exercise, and make new programs for the  stated effects.

8.4     Review the use of the fix adverb in Exercises 7.4-5, and
experiment with its use on the programs of Exercise 8.2.

9:  ATOP CONJUNCTION

The conjunction @ applies to two verbs to produce a verb that is
equivalent to applying the first atop the second. For example:
	TriplePowersOf2=. (3&*)@(2&^)
	TriplePowersOf2 0 1 2 3 4

3 6 12 24 48   

	CubeOfDiff=. (^&3)@-
	3 4 5 6 CubeOfDiff 6 5 4 3

_27 _1 1 27

   

	f=. ^@-  The rightmost function is first applied monadically; the second is 	
		         applied dyadically if possible.
	5 f 3	    	
7.38906		

	f 3

0.0497871

	g=. -@^
	5 g 3

_125

	g 3

_20.0855

A conjunction, like an adverb, is executed before verbs; the
leftargument of either is the entire verb phrase that precedes it.
Consequently, some (but not all) of the parentheses in the foregoing
definitions can be omitted. For example:

	COD=. ^&3@-
	3 4 5 6 COD 6 5 4 3

_27 _1 1 27

	TPO2=. 3&*@(2&^)
	TPO2 0 1 2 3 4

3 6 12 24 48

	tpo2=. 3&*@2&^  	  An error because the conjunction  @ is defined

|domain error			only for a verb right argument

|   tpo2=.  3&*@2&^


Exercises:

9.1     Cover the comments on the right, and state the effects of the
programs. Then cover the programs and rewrite them from the English
statements:

	mc=. (+/%#)@|:		Means of columns of table
	f=. +/@*:		Sum of squares of list
	g=. %:@f		Geometric length of list
	h=.{&' *'@(</)		Map of comparison (dyad)
	k=. i. h i.		Map  (monad)
	map=. {&'+-* %#$'		7-character map
	MAP=. map@(6&<.)@<.		Extended domain of map
	add=. MAP@ (i.+/i.)		Addition table map

10:  VOCABULARY

Memorizing lists of words is a tedious and ineffectual way to learn a
language, and better techniques should be employed:

A) Conversation with a laconic native speaker, that is, one that allows
you to do most of the talking.

B) Reading material of interest in its own right.

C) Learning how to use dictionaries and grammars so as to become
independent of teachers.

D) Attempting to write on any topic of interest in itself.

E) Paying attention to the structure of words so that known words will
provide clues to the unknown. For example, program (already analyzed)
is related to tele (far off) gram, which is in turn related to
telephone. Even tiny words may possess informative structure: atom
means not cuttable, from a  (not) and tom (as in tomeand microtome).

In the case of J:

A) The computer provides for precise and general conversation.

B) Texts such as Tangible Math [7] and Arithmetic [8] use the language
in a variety of topics.

C) The appended dictionary of J provides a complete and concise
dictionary and grammar.

D) Programming in J [6] provides guidance in writing programs, and
almost any topic provides problems of a wide range of difficulty.

E) Words possess considerable structure, as in +: and -: and *: and %:
for double, halve, square, and  square root. Moreover,  a beginner
can  assign  and  use  mnemonic  names appropriate  to  any  native
language,  as  in  sqrt=. %: and entier=.<. (French name) and sin=.1&o.
and SIN=.1&o.@(%&180@o.) (for sine in degrees).

We will hereafter introduce and use new primitives with little or no
discussion, assuming that the reader will experiment with them on the
computer, consult the dictionary to determine their meanings, or
perhaps infer their meanings from their structure. For example, the
appearance of the word o. suggests a circle; it was used dyadically
above to define the sine (one of the circular functions), and
monadically for the function pi times, that is, the circumference of a
circle when applied to its diameter.

For precise oral communication it may be best to use the names (or
abbreviations) of the symbols themselves, as in:

<	Left a (angle)	/	Slash	&	Amp (ersand)	%	Per( cent)
[	Left b (racket)	\	Back (slash)	@	At	;	Semi (colon)
{       Left c (urly bracket)   |       Stile   ^       Caret   ~
Tilde (       Left p (arenthesis)     _       (under) Bar     `
Grave   *       Star


Exercises:

10.1 Experiment with a revised version of the program MAP of Exercise
9.1, using the remainder or residue dyad (|) instead of the minimum
(<.), as in M=.map@(6&|)@<. and compare its results with those of MAP.

10.2 Experiment with the programs sin and SIN defined in this lesson.

10.3 Write programs using various new primitives found in the
vocabulary at the end of the book.

10.4 Update the table of notation prepared in Exercise 3.2.

11:  HOUSEKEEPING

In an extended session it may be difficult to remember the names
assigned to verbs and nouns; the foreign conjunction !: (detailed in
the appendix) provides facilities for displaying and erasing them. For
example:
	b=. 3* a=. i. 6
	sum=. +/
	tri=. sum\ a
	names=. 4!:1
	names 0	   names 3

õýÃýÃýýýÀ		õýýýýýÃýýýÀ
þaþbþtriþ		þnamesþsumþ
ÁýÂýÂýýýã		ÁýýýýýÂýýýã			

	erase=. 4!:55

	erase <'tri'
1
	names 0 3
õýÃýÃýýýýýÃýýýýýÃýýýÀ
þaþbþeraseþnamesþsumþ
ÁýÂýÂýýýýýÂýýýýýÂýýýã

	erase names 0

1 1

	names 0 3

õýýýýýÃýýýýýÃýýýÀ
þeraseþnamesþsumþ
ÁýýýýýÂýýýýýÂýýýã

It is also useful to be able to save a record of a session in a file so
that all results can be reconstituted. Thus:
	'abc' 0!:2&< ''   	NB. To file abc from keyboard
	sum=. +/
	sum b=. 2 3 4

9

	0!:2&< ''        	NB. Discontinue recording
	(erase=. 4!:55) (names=. 4!:1) 0 3

1 1 1 1

	0!:2&< 'abc'      	NB. Execute the script file abc
	sum=. +/
	sum b=. 2 3 4

9


Exercises:

11.1 Enter and experiment with the programs defined in this lesson.

12:  POWER AND INVERSE

The power conjunction (^:) is analogous to the power function (^ ). For
example:
	]a=. 10^ b=. i.5

1 10 100 1000 10000

	b

0 1 2 3 4

	%:a

1 3.16228 10 31.6228 100

	%: %: a

1 1.77828 3.16228 5.62341 10

	%: ^: 2 a

1 1.77828 3.16228 5.62341 10

	%: ^: 3 a

1 1.33352 1.77828 2.37137 3.16228

	%: ^: b a

1      10     100    1000   10000
1 3.16228      10 31.6228     100
1 1.77828 3.16228 5.62341      10
1 1.33352 1.77828 2.37137 3.16228
1 1.15478 1.33352 1.53993 1.77828

	(cos=. 2&o.) ^: b d=.1

1 0.540302 0.857553 0.65429 0.79348

	] y=. cos ^: _ d

0.739085

	y=cos y

1

Successive applications of cos appear to be converging to a limiting
value; the infinite power (cos ^: _) yields this limit.  A right
argument of _1  produces the inverse function. Thus:
	%: ^: _1 b

0 1 4 9 16

	*: b

0 1 4 9 16

	%: ^: (-b) b

0	1     2         3         4
0	1     4         9        16
0	1    16        81       256
0	1   256      6561     65536

0	1 65536 4.30467e7 4.29497e9


Exercises:

12.1 The square function *: is the inverse of the square root function
%: and %:^:_1 is therefore equivalent to *: . Look for, and experiment
with, other inverse pairs among the primitive functions in the
Vocabulary.

13:  READING AND WRITING

Cover the right side of the page and make a serious attempt to
translate the sentences on the left to English; that is, state
succinctly in English what the verb defined by each sentence does. Use
any available aids, including the dictionary and experimentation on the
computer:

	f1=. <:                	Decrement (monad); Less or equal
	f2=. f1&9	Less or equal 9
	f3=. f2 *. >:&2	Interval test 2 to 9 (inclusive)
	f4=. f3 *. <. = ]	In 2 to 9 and integer
	f5=. f3 +. <. = ] 	In 2 to 9 or integer

	g1=. %&1.8	Divide by 1.8
	g2=. g1^:_1	Multiply by 1.8
	g3=. -&32	Subtract 32
	g4=. g3^:_1	Add 32
	g5=. g1@g3	Celsius from Fahrenheit
	g6=. g5^:_1	Fahrenheit from Celsius


	h1=. >./	Maximum over list (monad)
	h2=. h1-<./               	Spread. Try h2 b with the parabola:
		     	   b=.(-&2 * -&3) -:i.12

   

	h3=. h1@]-i.@[*h2@]%<:@[	Grid. Try 10 h3 b
	h4=. h3 <:/ ]   	Barchart. Try 10 h4 b
	h5=. {&' *' @ h4	Barchart. Try 10 h5 b

After entering the foregoing definitions, enter each verb name alone to
display its definition, and learn to interpret the resulting displays.
To see several forms of display, first enter 9!:3 (2 4 5).

Cover the left side of the page, and translate the English definitions
on the right back into J.


Exercises:

13.1 These exercises are grouped by topic and organized like the
lesson, with programs that are first to be read and then to be
rewritten. However, a reader already familiar with a given topic might
begin by writing.

	A. Properties of numbers

	pn=. >:@i.		Positive numbers (e.g. pn 9)
	rt=. pn |/ pn		Remainder table
	dt=. 0&=@rt		Divisibility table
	nd=. +/@dt		Number of divisors
	prt=. 2&=@nd		Prime test
	prsel=. prt # pn		Prime select
	N=. >:@pn		Numbers greater than 1